Understanding Intelligent Calculation

In This Section:

Introducing Intelligent Calculation

Using Intelligent Calculation

Using the SET CLEARUPDATESTATUS Command

Calculating Data Blocks

Understanding the Effects of Intelligent Calculation

Introducing Intelligent Calculation

By default, when Essbase performs a full calculation of a database, it tracks which data blocks it calculates. If you then load a subset of data, on subsequent calculations, Essbase calculates only the data blocks that have not been calculated and the calculated blocks that require recalculation because of the new data. This process is called Intelligent Calculation.

By default, Intelligent Calculation is turned on. You can change this default setting in essbase.cfg. See the Oracle Essbase Technical Reference.

You can also turn Intelligent Calculation on or off in a calculation script. See Turning Intelligent Calculation On and Off.

For information on other calculation optimization methods, see:

Benefits of Intelligent Calculation

Intelligent Calculation is designed to provide significant calculation performance benefits for these types of calculations:

  • A full calculation of a database (CALC ALL), with some exceptions.

    See Limitations of Intelligent Calculation.

  • A calculation script that calculates all members in one CALC DIM statement.

  • For database calculations that cannot use Intelligent Calculation for the full calculation, you may be able to use Intelligent Calculation for part of the calculation.

    For example, to significantly improve calculation performance for a case in which you calculate a database by doing a default consolidation and then an allocation of data, enable Intelligent Calculation for the default consolidation and then disable Intelligent Calculation for the allocation.

    Assuming that Intelligent Calculation is turned on (the default), create a calculation script to perform these steps for a partial Intelligent Calculation:

    • Enable Intelligent Calculation, if it is disabled

    • Use CALC ALL to calculate the database

    • Use the SET UPDATECALC command to disable Intelligent Calculation

    • Allocate data

    • Optionally, enable Intelligent Calculation again

Intelligent Calculation and Data Block Status

To provide Intelligent Calculation, Essbase checks the status of the data blocks in a database. Data blocks have a calculation status of clean or dirty. Essbase marks a data block as clean after certain calculations.

When Intelligent Calculation is enabled, Essbase calculates only dirty blocks and their dependent parents. When disabled, Essbase calculates all data blocks, regardless of whether they are marked as clean or dirty.

Marking Blocks as Clean

Essbase marks data blocks as clean in these types of calculations:

  • A full calculation (CALC ALL) of a database (the default calculation).

  • A calculation script that calculates all the dimensions in one CALC DIM statement.

    For example, the following calculation script calculates all members in the Sample.Basic database:

    CALC DIM(Measures, Product, Market, Year, Scenario);

    Compare this calculation script to a calculation script that calculates all the members with two CALC DIM statements:

    CALC DIM(Measures, Product);
    CALC DIM(Market, Year, Scenario);

Using two CALC DIM statements causes Essbase to do at least two calculation passes through the database. In this calculation, Essbase does not, by default, mark the data blocks as clean. Because Intelligent Calculation depends on accurate clean and dirty status, you must manage these markers carefully. See Maintaining Clean and Dirty Status.

Essbase marks calculated data blocks as clean only in the situations described above, unless you use the SET CLEARUPDATESTATUS command in a calculation script. See Using the SET CLEARUPDATESTATUS Command.

Marking Blocks as Dirty

Essbase marks a data block as dirty in these situations:

  • Calculating the data block for a partial calculation of the database only if SET CLEARUPDATESTATUS AFTER is not part of the partial calculation statement in the calculation script

  • Loading data into the data block

  • Restructuring the database (for example, by adding a member to a dense dimension)

  • Copying data to the data block; for example, using DATACOPY

Maintaining Clean and Dirty Status

To use Intelligent Calculation when calculating a subset of a database or when performing multiple calculation passes through a database, consider carefully the implications of how Essbase marks data blocks as clean. When using Intelligent Calculation, you must accurately maintain the clean and dirty status of the data blocks to ensure that Essbase recalculates the database as efficiently as possible.

For example, when you calculate a subset of a database, the newly calculated data blocks are not marked as clean by default. You can ensure that the newly calculated blocks are marked as clean by using the SET CLEARUPDATESTATUS AFTER command in a calculation script. Before creating the calculation script, see Using the SET CLEARUPDATESTATUS Command and the Oracle Essbase Technical Reference.

Limitations of Intelligent Calculation

Consider the following limitations and situations when using Intelligent Calculation:

  • Intelligent Calculation works on a data block level and not on a cell level. For example, if you load a data value into one cell of a data block, the whole data block is marked as dirty.

  • A CALC ALL that requires two passes through the database may calculate incorrectly. The problem occurs because blocks that are marked clean during the first pass are skipped during the second pass. To avoid this problem, turn Intelligent Calculation off or perform a CALC DIM for each dimension (rather than a CALC ALL for the database). A CALC ALL requires two passes through the database in either of these situations:

    • When the accounts dimension is sparse

    • When the accounts dimension is dense, the time dimension is sparse, and there is at least one more dense dimension in the outline

  • Changing a formula on the database outline or changing an accounts property on the database outline does not cause Essbase to restructure the database. Therefore, Essbase does not mark the affected blocks as dirty. You must recalculate the appropriate data blocks. See Changing Formulas and Accounts Properties.

  • Whenever possible, Essbase calculates formulas that are tagged as two-pass and in the dimension tagged as accounts as part of the main calculation of a database. You may, however, need to use a calculation script to calculate some formulas twice. When you use a calculation script, disable Intelligent Calculation before recalculating formulas.

  • When SET CREATENONMISSINGBLK is set to ON in a calculation script, Intelligent Calculation is turned off, and affected blocks are calculated whether they are marked clean or dirty.

Using Intelligent Calculation

This section provides information on turning Intelligent Calculation on and off and using Intelligent Calculation with different types of calculations.

Turning Intelligent Calculation On and Off

By default, Intelligent Calculation is turned on. To change the default, use the UPDATECALC setting in the essbase.cfg file.

To turn Intelligent Calculation on and off for the duration of a calculation script, use the SET UPDATECALC command in a calculation script.

See the Oracle Essbase Technical Reference.

Using Intelligent Calculation for a Default, Full Calculation

Intelligent Calculation provides significant performance benefits when you do a full calculation (CALC ALL) of a database. If you do a full calculation, leave Intelligent Calculation turned on (the default) to take advantage of its performance benefits.

*  To check the current calculation setting, see “Setting the Default Calculation” in the Oracle Essbase Administration Services Online Help.

Caution!

When using Intelligent Calculation, note the information in Limitations of Intelligent Calculation.

    Calculating for the First Time

    When you do the first full calculation of a database, Essbase calculates every block. The performance is the same whether Intelligent Calculation is on or off.

    Recalculating

    When you do a full recalculation of a database with Intelligent Calculation turned on, Essbase checks each block to see whether it is marked as clean or dirty. See Intelligent Calculation and Data Block Status.

    Checking data blocks has a 5% to 10% performance overhead, which is insignificant when compared to the performance gained by enabling Intelligent Calculation.

    If, however, you recalculate a database in which more than approximately 80% of the values have changed, the overhead of Intelligent Calculation may outweigh the benefits. In this case, disable Intelligent Calculation.

    Using Intelligent Calculation for a Calculation Script, Partial Calculation

    Essbase marks a data block as clean when it calculates the data block on a full calculation (CALC ALL) or when it calculates all dimensions in one CALC DIM command. See Marking Blocks as Clean.

    In any other calculations, Essbase does not mark calculated data blocks as clean, unless you use the SET CLEARUPDATESTATUS command in a calculation script. For example, if you calculate a subset of a database or calculate a database in two calculation passes, Essbase does not mark the calculated blocks as clean, unless you use the SET CLEARUPDATESTATUS command.

    The following calculation scripts do not cause Essbase to mark the calculated data blocks as clean:

    FIX(“New York”)
       CALC DIM(Product, Measures);
    ENDFIX
    CALC DIM(Measures, Product);
    CALC DIM(Market, Year, Scenario);

    Use SET CLEARUPDATESTATUS to avoid unnecessary recalculations.

    Using the SET CLEARUPDATESTATUS Command

    In some cases, Essbase does not mark calculated blocks as clean; for example, if you calculate a subset of a database or calculate a database in two calculation passes. To manually mark data blocks as clean for purposes of Intelligent Calculation, use the SET CLEARUPDATESTATUS command in a calculation script. Read this section, and also see Intelligent Calculation and Data Block Status.

    Understanding SET CLEARUPDATESTATUS

    The SET CLEARUPDATESTATUS command has three parameters—AFTER, ONLY, and OFF.

    • SET CLEARUPDATESTATUS AFTER;

      Essbase marks calculated data blocks as clean, even if it is calculating a subset of a database.

    • SET CLEARUPDATESTATUS ONLY;

      Essbase marks the specified data blocks as clean but does not calculate the data blocks. This parameter provides the same result as AFTER, but without calculation.

    • SET CLEARUPDATESTATUS OFF;

      Essbase calculates the data blocks but does not mark the calculated data blocks as clean. Data blocks are not marked as clean, even on a full calculation (CALC ALL) of a database. The existing clean or dirty status of the calculated data blocks remains unchanged.

    Choosing a SET CLEARUPDATESTATUS Setting

    When you use the SET CLEARUPDATESTATUS command to mark calculated data blocks as clean, be aware of these recommendations before selecting the parameter (AFTER, ONLY, OFF):

    • Only calculated data blocks are marked as clean.

    • Do not use the SET CLEARUPDATESTATUS AFTER command with concurrent calculations unless you are certain that the concurrent calculations do not need to calculate the same data block or blocks. If concurrent calculations attempt to calculate the same data blocks, with Intelligent Calculation enabled, Essbase does not recalculate the data blocks if the data blocks are already marked clean by the other concurrent calculation. See Handling Concurrent Calculations.

    • When Essbase calculates data blocks on a first calculation pass through a database, it marks the data blocks as clean. If you try to calculate the same data blocks on a subsequent pass with Intelligent Calculation enabled, Essbase does not recalculate the data blocks, because they are already marked as clean.

    Reviewing Examples That Use SET CLEARUPDATESTATUS

    Assume a scenario using the Sample.Basic database:

    • Sparse dimensions are Market and Product.

    • New York is a member on the sparse Market dimension.

    • Intelligent Calculation is turned on (the default).

    These examples show different ways of using SET CLEARUPDATESTATUS:

    Example 1: CLEARUPDATESTATUS AFTER

    SET CLEARUPDATESTATUS AFTER;
    FIX(“New York”)
       CALC DIM(Product);
    ENDFIX

    In this example, Essbase searches for dirty parent data blocks for New York (for example New York -> Colas, in which Colas is a parent member on the Product dimension). It calculates these dirty blocks and marks them as clean. Essbase does not mark the level 0 data blocks as clean, because they are not calculated. For information on level 0 blocks, see Defining Calculation Order.

    Example 2: CLEARUPDATESTATUS ONLY

    SET CLEARUPDATESTATUS ONLY;
    FIX(“New York”)
       CALC DIM(Product);
    ENDFIX

    Essbase searches for dirty parent data blocks for New York (for example New York -> Colas, in which Colas is a parent member on the Product dimension). Essbase marks the dirty parent data blocks as clean but does not calculate the data blocks. Essbase does not mark the level 0 data blocks as clean because they are not calculated. For example, if New York -> 100-10 (a level 0 block) is dirty, it remains dirty.

    Example 3: CLEARUPDATESTATUS OFF

    SET CLEARUPDATESTATUS OFF;
    CALC ALL;
    CALC TWOPASS;
    SET CLEARUPDATESTATUS ONLY;
    CALC ALL;

    In this example, Essbase first calculates all the dirty data blocks in the database. The calculated data blocks remain dirty. Essbase does not mark them as clean.

    Essbase then calculates the members tagged as two-pass that are in the dimension tagged as accounts. Because the data blocks are still marked as dirty, Essbase recalculates them. Again, it does not mark the calculated data blocks as clean.

    Essbase then searches for all the dirty blocks in the database and marks them as clean. It does not calculate the blocks, although a CALC ALL command is used.

    Calculating Data Blocks

    Essbase creates a data block for each unique combination of sparse dimension members, provided that at least one data value exists for the combination. Each data block represents all dense dimension member values for that unique combination of sparse dimension members.

    For example, in the Sample.Basic database, the Market and Product dimensions are sparse. Therefore, the data block New York -> Colas represents all the member values on the Year, Measures, and Scenario dimensions for the sparse combination New York -> Colas.

    These sections assume that you are familiar with the concepts of upper-level, level 0, and input data blocks. See Data Storage in Data Blocks.

    Calculating Dense Dimensions

    When you calculate a dense dimension and do not use a FIX command, Essbase calculates at least some of the data values in every data block in the database.

    For example, the following calculation script is based on the Sample.Basic database:

    SET CLEARUPDATESTATUS AFTER;
    CALC DIM(Year);

    This script calculates the Year dimension, which is a dense dimension. Because Year is dense, every data block in the database includes members of the Year dimension. Therefore, Essbase calculates data values in every data block. Because the script uses the SET CLEARUPDATESTATUS AFTER command, Essbase marks all data blocks as clean.

    Calculating Sparse Dimensions

    When you calculate a sparse dimension, Essbase may not need to calculate every data block in the database.

    For example, the following calculation script is based on the Sample.Basic database:

    SET CLEARUPDATESTATUS AFTER;
    CALC DIM(Product);

    This script calculates the Product dimension, which is a sparse dimension. Because Product is sparse, a data block exists for each member on the Product dimension. For example, one data block exists for New York -> Colas and another for New York -> 100-10.

    Level 0 Effects

    The data block New York -> 100-10 is a level 0 block; it does not represent a parent member on either sparse dimension (Market or Product). The data values for New York -> 100-10 are input values; they are loaded into the database. Therefore, Essbase does not need to calculate this data block. Nor does Essbase mark the data block for New York -> 100-10 as clean, even though the script uses the SET CLEARUPDATESTATUS AFTER command.

    Note:

    Essbase calculates level 0 data blocks if a corresponding sparse, level 0 member has a formula applied to it.

    If you load data into a database, the level 0 data blocks into which you load data are marked as dirty. If you subsequently calculate only a sparse dimension or dimensions, the level 0 blocks remain dirty, because Essbase does not calculate them. Therefore, when you recalculate only a sparse dimension or dimensions, Essbase recalculates all upper-level data blocks, because the upper-level blocks are marked as dirty if their child blocks are dirty, although the upper-level blocks were originally clean.

    Upper-Level Effects

    Colas is a parent-level member on the Product dimension. Essbase must calculate values for Colas, so Essbase calculates this data block. Because the script uses the SET CLEARUPDATESTATUS AFTER command, Essbase marks the data block as clean.

    When Essbase calculates a sparse dimension, it recalculates an upper-level data block if the block is dependent on one or more dirty child blocks.

    Unnecessary Calculation

    You can avoid unnecessary calculation by calculating at least one dense dimension. When you calculate a dense dimension and do not use the FIX command, data values are calculated in every data block, including the level 0 blocks. So the level 0 blocks are marked as clean.

    Handling Concurrent Calculations

    If concurrent calculations attempt to calculate the same data blocks, and Intelligent Calculation is turned on, Essbase may not recalculate the data blocks, because they are already marked as clean.

    In the following example, based on the Sample.Basic database, Actual and Budget are members of the dense Scenario dimension. Because Scenario is dense, each data block in the database contains Actual and Budget values. If User 1 runs the following calculation script, Essbase calculates the Actual values for all data blocks that represent New York. Essbase marks the calculated data blocks as clean, although not all the data values in each calculated block have been calculated. For example, the Budget values have not been calculated.

    SET CLEARUPDATESTATUS AFTER;
    FIX(“New York”, Actual)
       CALC DIM(Product, Year);
    ENDFIX

    If User 2 runs the following calculation script to calculate the Budget values for New York, Essbase does not recalculate the specified data blocks, because they are already marked as clean. The calculation results for Budget are not correct.

    SET CLEARUPDATESTATUS AFTER;
    FIX(“New York”, Budget)
       CALC DIM(Product, Year);
    ENDFIX

    One way to solve this problem is to make the Scenario dimension sparse. Then the Actual and Budget values are in different data blocks; for example, New York -> Colas -> Actual and New York -> Colas -> Budget. In this case, the second calculation script correctly calculates Budget data block.

    Running concurrent calculations might require an increase in the data cache. See Sizing the Data Cache.

    Understanding Multiple-Pass Calculations

    Whenever possible, Essbase calculates a database in one calculation pass through the database. See Calculation Passes.

    When you use a calculation script to calculate a database, the number of calculation passes that Essbase performs depends upon the calculation script. See Intelligent Calculation and Data Block Status and Grouping Formulas and Calculations.

    For example, assume that Essbase calculates data blocks on a first calculation pass through a database and marks them as clean. If you attempt to calculate the same data blocks on a subsequent pass and Intelligent Calculation is enabled, Essbase does not recalculate the data blocks, because they are already marked as clean.

    Reviewing Examples and Solutions for Multiple-Pass Calculations

    These examples describe situations that produce incorrect calculation results and provide a solution to obtain correct results. They are based on the Sample.Basic database and assume that Intelligent Calculation is turned on.

    Example 1: Intelligent Calculation and Two-Pass

    This calculation script does a default calculation and then a two-pass calculation:

    CALC ALL;
    CALC TWOPASS;

    Error

    Essbase calculates the dirty data blocks in the database and marks all the data blocks as clean. Essbase then needs to recalculate the members tagged as two-pass in the dimension tagged as accounts. However, Essbase does not recalculate the specified data blocks because they are already marked as clean. The calculation results are not correct.

    Solution

    You can calculate the correct results by disabling Intelligent Calculation for the two-pass calculation.

    Example 2: SET CLEARUPDATESTATUS and FIX

    This calculation script calculates data values for New York. The calculation is based on the Product dimension:

    SET CLEARUPDATESTATUS AFTER;
    FIX(“New York”)
       CALC DIM(Product);
    ENDFIX
    CALC TWOPASS;

    Error

    *  Essbase performs the following processes:

    1. Essbase cycles through the database calculating the dirty data blocks that represent New York. The calculation is based on the Product dimension. Thus, Essbase calculates only the blocks that represent a parent member on the Product dimension (for example, New York -> Colas, New York -> Root Beer, and New York -> Fruit Soda), and then only calculates the aggregations and formulas for the Product dimension.

    2. Because the SET CLEARUPDATESTATUS AFTER command is used, Essbase marks the calculated data blocks as clean, although not all data values in each calculated block have been calculated.

    3. Essbase should recalculate the members tagged as two-pass in the dimension tagged as accounts; however, some of these data blocks are already marked as clean from the calculation in step 2. Essbase does not recalculate the data blocks that are marked as clean. The calculation results are not correct.

    Solution

    You can calculate the correct results by disabling Intelligent Calculation for the two-pass calculation.

    Example 3: SET CLEARUPDATESTATUS and Two CALC DIM Commands

    This calculation script bases the database calculation on the Product and Year dimensions. Because two CALC DIM commands are used, Essbase does two calculation passes through the database:

    SET CLEARUPDATESTATUS AFTER;
    CALC DIM(Product);
    CALC DIM(Year);

    Error

    *  Essbase performs the following processes:

    1. Essbase cycles through the database calculating the dirty data blocks. The calculation is based on the Product dimension, as in Example 2: SET CLEARUPDATESTATUS and FIX.

    2. Because the SET CLEARUPDATESTATUS AFTER command is used, Essbase marks the calculated data blocks as clean, although not all data values in each calculated block have been calculated.

    3. Essbase should recalculate the data blocks. The recalculation is based on the Year dimension. However, as a result of the calculation in step 2, some data blocks are already marked as clean, and Essbase does not recalculate them. The calculation results are not correct.

    Solution

    You can calculate the correct results by using one CALC DIM command to calculate the Product and Year dimensions. Essbase calculates both dimensions in one calculation pass through the database. The following calculation script calculates the correct results:

    SET CLEARUPDATESTATUS AFTER;
    CALC DIM(Product, Year);

    Note:

    When you calculate several dimensions in one CALC DIM command, Essbase calculates the dimensions in the default calculation order and not in the order in which you list them in the command. See Member Calculation Order.

    Example 4: Two Calculation Scripts

    This example calculates data values for New York but calculates based on two dimensions using two calculation scripts. The first calculation script calculates the Product dimension:

    SET CLEARUPDATESTATUS AFTER;
    FIX(“New York”)
       CALC DIM(Product);
    ENDFIX

    Essbase calculates the data blocks that include New York. Because the calculation is based on the Product dimension, Essbase calculates only the dirty blocks that include a parent member on the Product dimension (for example, New York -> Colas, New York -> Root Beer, and New York -> Fruit Soda), and calculates only the aggregations and formulas for the Product dimension.

    Because of the CLEARUPDATESTATUS AFTER command, Essbase marks the calculated data blocks as clean, although not all data values in each calculated block have been calculated.

    The second calculation script calculates the Year dimension:

    SET CLEARUPDATESTATUS AFTER;
    FIX(“New York”)
       CALC DIM(Year);
    ENDFIX

    Essbase calculates the data blocks that represent New York. Because the calculation is based on the Year dimension, which is a dense dimension, Essbase should calculate all data blocks that include New York, although within each block Essbase calculates only the aggregations and formulas for the Year dimension.

    Error

    As a result of the first calculation, some data blocks for New York are already marked as clean. Essbase does not recalculate these data blocks with the second calculation script because the data blocks are marked as clean. The calculation results are not correct.

    Solution

    You can calculate the correct results by telling Essbase not to mark the calculated data blocks as clean. The following calculation script calculates the correct results:

    SET CLEARUPDATESTATUS OFF;
    FIX(“New York”)
       CALC DIM(Product);
    ENDFIX
    SET CLEARUPDATESTATUS AFTER;
    FIX(“New York”)
       CALC DIM(Year);
    ENDFIX

    With the SET CLEARUPDATESTATUS OFF command, Essbase calculates dirty data blocks but does not to mark them as clean, unlike the SET CLEARUPDATESTATUS AFTER command.

    This solution assumes that the data blocks are not marked as clean from a previous partial calculation of the database.

    You can ensure that all data blocks are calculated, regardless of their status, by disabling Intelligent Calculation. The following calculation script calculates all specified data blocks, regardless of their clean or dirty status:

    SET UPDATECALC OFF;
    FIX(“New York”)
       CALC DIM(Year, Product);
    ENDFIX

    Because you have not used the SET CLEARUPDATESTATUS AFTER command, Essbase does not mark calculated data blocks as clean.

    Understanding the Effects of Intelligent Calculation

    Using Intelligent Calculation may have implications for how you administer a database. This section discusses the implications of each action.

    Changing Formulas and Accounts Properties

    Because neither changing a formula in the database outline nor changing an accounts property in the database outline causes Essbase to restructure the database, data blocks affected by such a change are not marked as dirty. For example, if you change a time balance tag in the dimension tagged as accounts, Essbase does not restructure the database and does not mark the affected blocks as dirty.

    When you subsequently run a default calculation with Intelligent Calculation turned on, the changes are not calculated. To recalculate the appropriate data blocks, use a calculation script to perform any of the following tasks:

    • Disable Intelligent Calculation and calculate the member formula that has changed.

    • Disable Intelligent Calculation and use the FIX command to calculate the appropriate subset of a database.

    • Disable Intelligent Calculation and perform a default CALC ALL on a database.

    Using Relationship and Financial Functions

    If you use relationship functions (for example, @PRIOR or @NEXT) or financial functions (for example, @ACCUM, @NPV, or @INTEREST) in a formula on a sparse dimension or a dense dimension, Essbase always recalculates the data block that contains the formula.

    See the Oracle Essbase Technical Reference.

    Restructuring Databases

    When you restructure a database (for example, by adding a member to a dense dimension), all data blocks potentially need recalculating. Therefore, Essbase marks all data blocks as dirty. When you calculate the restructured database, all blocks are calculated.

    Note:

    Changing a formula in the database outline or changing an accounts property in the database outline does not cause Essbase to restructure the database. You must recalculate the appropriate data blocks. See Changing Formulas and Accounts Properties.

    Copying and Clearing Data

    When you copy values to a data block by using the DATACOPY command, the resulting data block is marked as dirty. Essbase calculates the block when you recalculate a database.

    When you clear data values by using the CLEARDATA and CLEARBLOCK commands, Essbase clears all the blocks regardless of how they are marked.

    Converting Currencies

    When you convert currencies using the CCONV command, the resulting data blocks are marked as dirty. Essbase calculates all converted blocks when you recalculate a database.